GZDoom + GZDoom Builder Error

My guess is that you have Stimbonus first in your DECORATE lump, so line 4 would be there. You don't have it inheriting from any class, so Inventory.Pickupmessage is not defined. If you inherit from HealthBonus, that should fix it.

Please show us the  code that is generating this error message, or upload the wad for us to see if we can figure it out.

Sure thing.

MP40
actor MP40 : DoomWeapon 12304
{
   Weapon.SelectionOrder 700
   Weapon.AmmoUse 1
   Weapon.AmmoGive 20
   Weapon.AmmoType "Clip"
   Inventory.PickupMessage "You got the MP40!"
   Obituary "%o was riddled by %k's MP40."
   attacksound "MP40/Fire"
   Decal "BulletChip"
   Weapon.SlotNumber 4
   Scale 0.5
   States
   {
   Ready:
     MP40 A 1 A_WeaponReady
     Loop
   Deselect:
     MP40 A 1 A_Lower
     Loop
   Select:
     MP40 A 1 A_Raise
     Loop
   Fire:
     MP40 B 2 Bright A_FireBullets (5, 4, 1, 5, "BulletPuff")
     MP40 B 0 A_GunFlash
     MP40 D 1 A_SetPitch (pitch-0.4) 
     MP40 CA 1 A_SetPitch (pitch+0.2) 
     MP40 A 0 A_ReFire
     Goto Ready
   Flash:
     TNT1 A 5 Bright A_Light1
     Goto LightDone
     TNT1 A 5 Bright A_Light1
     Goto LightDone
   Spawn:
     MP40 E -1
     Stop
   }
}
 

Angled Flashlight 
ACTOR FlashLightAngled : Weapon 15017
{ 
    Weapon.SlotNumber 0
    Weapon.Selectionorder 4000
    Inventory.PickupSound "misc/p_pkup"
    Inventory.PickupMessage "Picked up a flashlight!"
    Scale 0.75
    +NOALERT
    +NOAUTOFIRE
    +NOAUTOAIM
    +NOTRIGGER
    States 
    { 
    Spawn: 
        FLSH A -1 
        Loop 
    Ready: 
        FLIT A 1 A_WeaponReady 
        Loop 
        FLIT A 0 A_Light2
        FLIT A 1 A_WeaponReady
        FLIT A 0 A_FireBullets( 0, 0, 1, 0, "FlashLBeam", FBF_NOFLASH | FBF_NORANDOMPUFFZ, 1500)
        Goto Ready+2
    Deselect:
        FLIT A 0 A_JumpIfInventory("SwitchOn", 1, "LightLower")
    Lower:
        FLIT A 0 A_Light0
        FLIT A 1 A_Lower 
        Loop
    LightLower:
        FLIT A 0 A_PlaySound("flashlight/off")
        FLIT A 0 A_TakeInventory("SwitchOn", 1)
    TrueLightLower:
        FLIT A 0 A_Light0
        FLIT A 1 A_Lower 
        Loop
    Select: 
        FLIT A 1 A_Raise 
        Loop 
    Fire: 
        FLIT A 1 A_JumpIfInventory("SwitchOn", 1, 4)
        FLIT A 1 A_PlaySound("flashlight/on")
        FLIT A 1 A_Light2 
        FLIT A 1 A_GiveInventory("SwitchOn", 1)  
        Goto Ready+2  
        FLIT A 1 A_PlaySound("flashlight/off")
        FLIT A 1 A_Light0 
        FLIT A 1 A_TakeInventory("SwitchOn", 1)  
        Goto Ready
    } 
} 

Centered Flashlight

ACTOR FlashLightCentered : Weapon 15019
{
    Weapon.SlotNumber 0
    Weapon.Selectionorder 4000
    Inventory.PickupSound "misc/p_pkup" 
    Inventory.PickupMessage "Picked up a flashlight!"
    Scale 0.75
    +NOALERT
    +NOAUTOFIRE
    +NOAUTOAIM
    States
    {
    Spawn: 
        FLSH B -1 
        Loop 
    Ready: 
        FLIT B 1 A_WeaponReady 
        Loop 
        FLIT B 0 A_Light2
        FLIT B 1 A_WeaponReady
        FLIT B 0 A_FireBullets( 0, 0, 1, 0, "FlashLBeam", FBF_NOFLASH | FBF_NORANDOMPUFFZ, 1500)
        Goto Ready+2
    Deselect:
        FLIT B 0 A_JumpIfInventory("SwitchOn", 1, "LightLower")
    Lower:
        FLIT B 0 A_Light0
        FLIT B 1 A_Lower 
        Loop
    LightLower:
        FLIT B 0 A_PlaySound("flashlight/off")
        FLIT B 0 A_TakeInventory("SwitchOn", 1)
    TrueLightLower:
        FLIT B 0 A_Light0
        FLIT B 1 A_Lower 
        Loop
    Select: 
        FLIT B 1 A_Raise 
        Loop
    Fire: 
        FLIT B 1 A_JumpIfInventory("SwitchOn", 1, 4)
        FLIT B 1 A_PlaySound("flashlight/on")
        FLIT B 1 A_Light2 
        FLIT B 1 A_GiveInventory("SwitchOn", 1)  
        Goto Ready+2  
        FLIT B 1 A_PlaySound("flashlight/off")
        FLIT B 1 A_Light0 
        FLIT B 1 A_TakeInventory("SwitchOn", 1)  
        Goto Ready
    } 
} 

Medipack

Actor Medipack : Health 10394
{
 Game Doom
 Inventory.Amount 50
 Inventory.PickupMessage "Picked up a medipack."
 Health.LowMessage 20, "Picked up a medipack that you REALLY need!"
    States
    {
        Spawn:
        MEDP A -1
        Stop
    }
}

Food

Actor Food : Health 15035
{
 Game Doom
 Inventory.Amount 15
 Inventory.PickupMessage "Picked up a plate of food."
 Health.LowMessage 20, "Picked up a plate of food that you REALLY need!"
 Inventory.PickupSound "pickup/food"
 States
{
 Spawn:
 FOOD A -1
 Stop
 }
}

First-Aid Kit

Actor FirstAidKit : Health 15036
{
 Game Doom
 Inventory.Amount 25
 Inventory.PickupMessage "Picked up a first-aid kit."
 Health.LowMessage 20, "Picked up a first-aid kit that you REALLY need!"
 Inventory.PickupSound "pickup/medkit"
 States
{
 Spawn:
 MEDK A -1
 Stop
 }
}

ArmorShard

actor ArmorShard : ArmorBonus 10395
{
    Inventory.Pickupmessage "Picked up an Armor Shard."
    Inventory.Icon "ARSDA0"
    Inventory.PickupSound "pickup/armorshard"
    Armor.Saveamount 5
    States
    {
    Spawn:
        ARSD ABCDCB 6
        loop
    }
}

Stimbonus

actor Stimbonus 10396
{
    +COUNTITEM
    Inventory.Pickupmessage "Picked up a Stimbonus."
    Inventory.Amount 5
    Inventory.MaxAmount 200
    Scale 0.75
    States
    {
    Spawn:
        SMBS A -1
        stop
    }
}

I do believe that's all of them that have the Inventory.Pickupmessage.

It worked! Thanks for the help.