Jump to content
Search In
  • More options...
Find results that contain...
Find results in...
  • 0
JohnCook1994

The Decorate Weapon Bug

Asked by JohnCook1994

Question

JohnCook1994   

JohnCook1994
Posted

Hello guys,

 

I have a major problem with the Napalm Launcher that I was going to use on my custom class, Caleb. I downloaded the Napalm Launcher from Realm667's website, and it did work for a little bit. Once I was doing level 2 on my map. Or any map, the Napalm Launcher seems to not work at all. It won't fire or won't EVEN let me deselect the napalm launcher. I do not know what I've done was wrong. I do have a pk3 file and updated my GZDOOM to it's the current version. It kinda feels like this weapon wants this pk3 to commit suicide. Is there anything I could do for that Napalm Launcher to work again, let me know.      Thank you, John Cook

0

Share this post

Link to post

5 answers to this question

Recommended Posts

  • 0

-TDRR-   

-TDRR-
Posted (edited)

You need to show us the DECORATE code for the weapon, or all help will be basically a wild guess.

0

Share this post

Link to post
  • 0

JohnCook1994   

JohnCook1994
Posted
Spoiler

 

ACTOR NapalmLauncher : Weapon
{
  Scale 0.6
  Radius 20
  Height 16
  Decal "Scorch"
  Inventory.PickupMessage "You got the napalm!"
  Obituary "%k loves the smell of %o's carcass in the morning!"
  Weapon.SlotNumber 5
  Weapon.SelectionOrder 900
  Weapon.KickBack 500
  Weapon.AmmoType "rocketammo"
  Weapon.AmmoUse 1
  Weapon.AmmoGive 40
  Weapon.AmmoType2 "rocketammo"
  Weapon.AmmoUse2 10
  +WEAPON.EXPLOSIVE

  States
  {
  Ready:
    NLAN BBBBCCCCDDDDEEEEAAAA 1 A_GiveInventory("Item_CheckAltFireAmmo")
    Loop
  Deselect:
    NLAN B 0 A_Lower
    NLAN BB 0 A_Lower
    Loop
  Select:
    NLAN B 0 A_Raise
    NLAN BB 0 A_Raise
    Loop
  Fire:
    NLAN F 0 A_PlaySound("dsnapalm")
    NLAN F 0 A_FireCustomMissile("NRocket", random(-1, 1), TRUE, 5, 3 + random(-1, 1))
    NLAN F 2 Bright A_GunFlash
    NLAN GHIJ 2 Bright
    NLAN KL 2
    NLAN B 4
    NLAN L 0 A_ReFire
    Goto Ready
  AltFire:
    NLAN F 0 A_PlaySound("dsNAPLM2", CHAN_WEAPON)
    NLAN F 0 A_FireCustomMissile("NapalmRocketAlt1", random(-2, 2), TRUE, 5, 3 + random(-2, 2))
    NLAN F 2 Bright A_GunFlash
    NLAN GHIJ 2 Bright
    NLAN KL 2
    NLAN B 4
    NLAN L 0 A_ReFire
    Goto Ready
  Flash:
    TNT1 A 6 A_Light2
    TNT1 A 6 A_Light1
    Goto LightDone

  }
}

ACTOR NRocket
{
  Radius 8
  Height 8
  Speed 45
  Damage 50
  Projectile
  DamageType "FriendlyFire"
  +RANDOMIZE
  Decal "Scorch"
  Scale 0.4
  DeathSound "NPLMBL"
  States
  {
  Spawn:
    FBA2 AABBCCDDEEFF 1 Bright A_CustomMissile("NRocketTrail", 0, 0, 0, CMF_AIMOFFSET | CMF_TRACKOWNER)
    Loop
  Death:
    TNT1 A 0 A_Explode
    TNT1 A 0 A_Scream
    TNT1 A 0 Radius_Quake(10, 8, 0, 15, 0)
    TNT1 A 0 A_SpawnItem("NRocketExplo")
    Stop
  }
}

ACTOR NRocketTrail
{
  Projectile
  Height 2
  Radius 2
  Scale 0.44
  Alpha 0.2
  RenderStyle "Translucent"
  States
  {
  Spawn:
    WPXS ABCDEFGHIJKLMNOPQRSTUVWXYZ 1 Bright
    WPXZ ABC 1 Bright A_FadeOut
    Stop
  }
}

ACTOR NRocketExplo
{
  Projectile
  Height 2
  Radius 2
  States
  {
  Spawn:
    EXP2 ABCDEFGHIJKLMN 2 Bright A_SetTranslucent(1.0, 1)
    Stop
  }
}

ACTOR NapalmRocketAlt1
{
  Decal "Scorch"
  Radius 11
  Height 8
  Speed 20
  RenderStyle "Add"
  Scale 0.5
  Damage 40
  DeathSound "NPLMBL"
  Projectile
  +RANDOMIZE
  +DONTSPLASH
  +EXTREMEDEATH
  -NOGRAVITY
  States
  {
  Spawn:
    FBA2 A 1 Bright A_SpawnItem("BSmokeTrail")
    MANF A 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 A 1 Bright A_SpawnItem("BSmokeTrail")
    MANF A 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 B 1 Bright A_SpawnItem("BSmokeTrail")
    MANF B 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 B 1 Bright A_SpawnItem("BSmokeTrail")
    MANF B 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 C 1 Bright A_SpawnItem("BSmokeTrail")
    MANF C 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 C 1 Bright A_SpawnItem("BSmokeTrail")
    MANF C 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 D 1 Bright A_SpawnItem("BSmokeTrail")
    MANF D 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 D 1 Bright A_SpawnItem("BSmokeTrail")
    MANF D 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 E 1 Bright A_SpawnItem("BSmokeTrail")
    MANF E 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 E 1 Bright A_SpawnItem("BSmokeTrail")
    MANF E 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 A 1 Bright A_SpawnItem("BSmokeTrail")
    MANF A 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 A 1 Bright A_SpawnItem("BSmokeTrail")
    MANF A 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 B 1 Bright A_SpawnItem("BSmokeTrail")
    MANF B 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 B 1 Bright A_SpawnItem("BSmokeTrail")
    MANF B 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 C 1 Bright A_SpawnItem("BSmokeTrail")
    MANF C 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    FBA2 C 1 Bright A_SpawnItem("BSmokeTrail")
    MANF C 0 Bright A_SpawnItem("BFireTrail", 8 + random(-5, 5), random(-5, 5))
    Goto Death
  Death:
    MISL A 0 A_Explode
    MISL A 0 A_PlaySound("NPLMBL")
    MISL B 0 A_SpawnItem("NapalmKaboom", -32, random(-2, 2))
    MISL BBB 0 A_ThrowGrenade("NapalmRocketAlt2", -30 + random(-5, 5), 10 + random(-5, 5), 5 + random(-5, 5))
    EXP2 ABCDEFGHIJKLMN 2 Bright
    Stop
  }
}

ACTOR BSmokeTrail
{
  Radius 13
  Height 8
  RenderStyle "Translucent"
  Alpha 0.30
  Scale 0.1
  +NOBLOCKMAP
  +RANDOMIZE
  +NOGRAVITY
  +DONTSPLASH
  +WINDTHRUST
  States
  {
  Spawn:
    NSMK A 0 A_Jump(128, 24)//6
    NSMK GGGGHHHHIIIIJJJJKKKKLLLL 1 A_FadeOut(0.01)
    Stop
    NSMK AAAABBBBCCCCDDDDEEEEFFFF 1 A_FadeOut(0.01)
    Stop
  }
}

ACTOR BFireTrail : BulletPuff
{
  Radius 13
  Height 8
  RenderStyle "Add"
  Scale 0.3
  Alpha 0.9
  +NOBLOCKMAP
  +RANDOMIZE
  +NOGRAVITY
  +WINDTHRUST
  States
  {
  Spawn:
    FTRL A 0 A_Jump(128, 9)
    FTRL A 0 Bright A_Jump(220, 1, 2, 3, 4, 5, 6, 7)
    FTRL IJKLMNOP 4 Bright
    Stop
    FTRL A 0 Bright A_Jump(220, 1, 2, 3, 4, 5, 6, 7)
    FTRL ABCDEFGH 4 Bright
    Stop
  }
}

ACTOR NapalmKaboom
{
  Radius 2
  Height 40
  RenderStyle "Add"
  +NOBLOCKMAP
  +NOGRAVITY
  +DONTSPLASH
  +RANDOMIZE
  Projectile
  Scale 0.6
  States
  {
  Spawn:
    BFE1 B 0
    Goto Death
  Death:
    BFE1 AAA 0 A_CustomMissile("NapalmDebris", 0, 0, random(0, 360), CMF_AIMDIRECTION, random(-90, 90))
    //BFE1 A 0 A_SpawnDebris("NapalmDebris")
    BFE1 A 0 A_Jump(127, 12)
    EXP2 ABCDEFGHIJKLMN 2 Bright
    Stop
    EXP2 ABCDEFGHIJKLMN 2 Bright
    Stop
  }
}

ACTOR NapalmRocketAlt2 : NapalmRocketAlt1
{
  Speed 1
  +STRIFEDAMAGE
  Damage 20
  States
  {
  Spawn:
    FBA2 AABBCCDDEEAABBCC 1 Bright A_SpawnItem("BSmokeTrail")
    Goto Death
  Death:
    MISL A 0 A_Explode
    MISL A 0 A_PlaySound("NPLMBL")
    MISL B 0 A_SpawnItem("NapalmKaboom", -32, random(-2, 2))
    MISL BBB 0 A_ThrowGrenade("NapalmRocketAlt3", -30 + random(-5, 5), 10 + random(-5, 5), 5 + random(-5, 5))
    EXP2 ABCDEFGHIJKLMN 2 Bright
    Stop
  }
}

ACTOR NapalmDebris
{
  Health 5
  Radius 1
  Height 1
  Speed 10
  Scale 0.2
  Projectile
  +NOBLOCKMAP
  +DONTSPLASH
  +RANDOMIZE
  -NOGRAVITY
  -SOLID
  +WINDTHRUST
  //RenderStyle "Add"
  States
  {
  Spawn:
    FSPK A 0 A_Jump(192, 3, 4, 6, 8)
    FSPK A 10 Bright
    FSPK A 200 Bright A_LowGravity
    Stop
    FSPK B 10 Bright
    FSPK B 200 Bright A_LowGravity
    Stop
    FSPK C 10 Bright
    FSPK C 200 Bright A_LowGravity
    Stop
    FSPK D 10 Bright
    FSPK D 200 Bright A_LowGravity
    Stop
    FSPK E 10 Bright
    FSPK E 200 Bright A_LowGravity
    Stop
  Death:
    FSPK A 1
    Stop
  }
}

ACTOR NapalmRocketAlt3 : NapalmRocketAlt1
{
  Speed 1
  +DOOMBOUNCE
  +STRIFEDAMAGE
  Damage 10
  BounceCount 2
  States
  {
  Spawn:
    FBA2 AABBCCDDEEAABBCCDDEEAABBCCDDEE 1 Bright A_SpawnItem("BSmokeTrail")
    Goto Death
  Death:
    MISL A 0 A_Explode
    MISL A 0 A_PlaySound("NPLMBL")
    MISL B 0 A_SpawnItem("NapalmKaboom", random(-4, 4), random(-2, 2))
    MISL BBB 0 A_ThrowGrenade("NapalmRocketAlt4", -30 + random(-5, 5), 10 + random(-5, 5), 5 + random(-5, 5))
    EXP2 ABCDEFGHIJKLMN 2 Bright
    Stop
  }
}

ACTOR NapalmRocketAlt4 : NapalmRocketAlt1
{
  Speed 5
  +DOOMBOUNCE
  +STRIFEDAMAGE
  +DONTSPLASH
  -EXTREMEDEATH
  Damage 5
  DamageType "Fire"
  BounceCount 2
  States
  {
  Spawn:
    FBA2 AABBCCDDEEAABBCCDDEEAABBCCDDEE 1 Bright A_SpawnItem("BSmokeTrail")
    Goto Death
  Death:
    MISL A 0 A_Explode
    MISL A 0 A_PlaySound("NPLMBL")
    MISL B 0 A_SpawnItem("NapalmKaboom", random(-4, 4), random(-2, 2))
    EXP2 ABCDEFGHIJKLMN 2 Bright
    Stop
  }
}

 

Alright, so I actually went through my CALEB Decorate and I copied the Napalm Launcher, which I somewhat edited before it glitched.

0

Share this post

Link to post
  • 0

Gaia74   

Gaia74
Posted (edited)

you modify the weapon?, i see a error

 

Deselect:
    NLAN B 0 A_Lower
    NLAN BB 0 A_Lower
    Loop
  Select:
    NLAN B 0 A_Raise
    NLAN BB 0 A_Raise
    Loop

 

This is looping infinite and second, you put in your caleb class, you use a keyconf?

0

Share this post

Link to post
  • 0

JohnCook1994   

JohnCook1994
Posted

I have a keyconf, just for player selection class

 

Spoiler

 

clearplayerclasses
addplayerclass "Doomguy"
addplayerclass "BJBlaskowicz"
addplayerclass "Caleb"
addplayerclass "Arya"


 

 

0

Share this post

Link to post
  • 0

JohnCook1994   

JohnCook1994
Posted

Alright, so I fixed it for now, I forgot to use A_WeaponReady, and deleted the NLAN BB 0 A_Raise and   NLAN BB 0 A_Lower. Thank you guys for helping me.

1

Share this post

Link to post

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Go To Question Listing Editing Questions
×