Question about original monsters and Decorate lumps

I'd like to know how to get an original monster to load. I've created a Decorate lump and have loaded it in my wad-file. The problem is, I don't know how to access him in the enemies section (he doesn't appear since he isn't a replacement of another demon). I'm using WadAuthor and ZDoom.

Thanks.

In Wadauthor you can put down a random Thing, then right-click on it and select "edit raw data". Then change the DoomEdNum to the one you created for your monster in the decorate lump.

First of all: You CANNOT use DECORATE to replace an existing thing. Everything defined in a DECORATE lump must be new and unique.

Second: WadAuthor doesnt read the DECORATE lump and you wont see your items. You can only enter their ID manually as Amaster mentioned. You could use Doom Builder, which will show the hings defined in DECORATE in the available things list automatically (and ofcourse allows you always to enter any custom thing ID manually as well). I believe Deepsea shows you the DECORATE things as well.

You can also create your own WadAuthor Configuration (.wcf file) from the zdoom one... you can add your own thing type, I think, although I've never done it. It has something to do with taking the thing number, and... doing something with it, I forget what. But I know it's possible. Yeah, I'm rather useless... :P

On a somewhat related note, what would a Pain Elemental and a Lost Soul look like if I wanted to create a definition for them but didn't want them to have parent attributes? I'm new to this so please be patient with my "newbie" power.

Pain Elemental:

ACTOR PainElemental 71
{
	Health 400
	Radius 31
	Height 56
	Mass 400
	Speed 8
	PainChance 128
	Monster
	+FLOAT +NOGRAVITY
	SeeSound "pain/sight"
	PainSound "pain/pain"
	DeathSound "pain/death"
	ActiveSound "pain/active"
	States
	{
	Spawn:
		PAIN A 10 A_Look
		Loop
	See:
		PAIN AABBCC 3 A_Chase
		Loop
	Missile:
		PAIN D 5 A_FaceTarget
		PAIN E 5 A_FaceTarget
		PAIN F 4 A_FaceTarget
		PAIN F 1 A_PainAttack
		Goto See
	Pain:
		PAIN G 6
		PAIN G 6 A_Pain
		Goto See
	Death:
		PAIN H 8
		PAIN I 8 A_Scream
		PAIN JK 8
		PAIN L 8 A_PainDie
		PAIN M 8
		Stop
	Raise:
		PAIN MLKJIH 8
		Goto See
	}
}

Lost Soul:

ACTOR LostSoul 3006
{
	Health 100
	Radius 16
	Height 56
	Mass 50
	Speed 8
	Damage 3
	PainChance 256
	Monster
	+FLOAT +NOGRAVITY +NOICEDEATH
	AttackSound "skull/melee"
	PainSound "skull/pain"
	DeathSound "skull/death"
	ActiveSound "skull/active"
	Obituary "%o was spooked by a lost soul."
	States
	{
	Spawn:
		SKUL AB 10 BRIGHT A_Look
		Loop
	See:
		SKUL AB 6 BRIGHT A_Chase
		Loop
	Missile:
		SKUL C 10 BRIGHT A_FaceTarget
		SKUL D 4 BRIGHT A_SkullAttack
		SKUL CD 4 BRIGHT
		Goto Missile+2
	Pain:
		SKUL E 3 BRIGHT
		SKUL E 3 BRIGHT A_Pain
		Goto See
	Death:
		SKUL F 6 BRIGHT A_NoGravity
		SKUL G 6 BRIGHT A_Scream
		SKUL H 6 BRIGHT
		SKUL I 6 BRIGHT A_Fall
		SKUL J 6
		SKUL K 6 
		Stop
	}
}

Note that the Lost Soul has one special property that cannot be expressed through DECORATE. Its attack range calculations are different from the other monsters.

Thanks.

The final question I have regarding this would be what would an Arch-Vile look like in decorate/without parent attributes? More specifically what would an Arch-Vile look like with the Arch-Vile flame (the one that consumes the player when an Arch-Vile attacks) trailing it? I'm requesting something similar to Russell Pearson's "Doom Raider" Arch-Vile (in the flame trail respect) if that helps to illustrate what I'm requesting.

Is there any documentation available that would quickly help me out? I'm completely new to this and although I have checked the ZDoom documentation(s) concerning this it still doesn't seem anymore "user-friendly" to me.

You can't do the Arch-Vile in DECORATE because you can't define the resurrecting state. That sequence is hard coded.