How do i put custom weapons into doom builder?

[Voidic]

I already got the placement down and you can pick it up, but you cant swap to it twice, if you swap to another weapon, ya cant use it, also, how do i replace the starting pistol? (The gun im using is the raptor handgun from realm667)

[Nevander]

To replace a weapon it's a bit more involved and I think at that point you do need a new class.

 

Change the Raptor code again

ACTOR Raptor : Weapon REPLACES Pistol 15006

Then set up the class, name it whatever

ACTOR NewClassName : DoomPlayer REPLACES DoomPlayer
{
   Player.StartItem "Raptor"
   Player.StartItem "Fist"
   Player.StartItem "Clip", 50
   Player.WeaponSlot 2, Raptor
}

Then in MAPINFO

gameinfo
{
   playerclasses = "NewClassName"
}

That should work.

[Nevander]

Well, the "putting into Doom Builder" part only includes giving the weapon actor a DoomEd number so it can be placed in maps. The rest is done completely within SLADE. Sounds like maybe you have not added the weapon to the player class or given it a weapon slot. If you are using a new player class, it must be included in playerclasses in a gameinfo block in MAPINFO.

[Voidic]

?

[Voidic]

Well heres the DECORATE script: 

ACTOR Raptor : Weapon
{
   Inventory.PickupSound "misc/w_pkup"
   Inventory.PickupMessage "You got the Raptor Handgun!"
   Weapon.AmmoType1 "Clip"
   Weapon.AmmoGive 12
   Weapon.AmmoUse1 2
   Weapon.KickBack 350
   Decal "BulletChip"
   States
   {
   Spawn:
      RPTP A -1
      Loop
   Ready:
      RPTN A 1 A_WeaponReady
      Loop
   Deselect:
      RPTN A 1 A_Lower
      Loop
   Select:
      RPTN A 1 A_Raise
      Loop
  Fire:
    TNT1 A 0 A_PlaySound("weapons/raptor")
    TNT1 A 0 A_GunFlash
    RPTN B 1 Bright A_FireBullets(2, 3, 2, 8, "RaptorPuff", 1)
    RPTN CD 1
    RPTN A 2
    TNT1 A 0 A_PlaySound("weapons/raptor")
    TNT1 A 0 A_GunFlash
    RPTN B 1 Bright A_FireBullets(2, 3, 2, 8, "RaptorPuff", 1)
    RPTN CD 1
    RPTN A 12
    RPTN A 1 A_ReFire
    Goto Ready 
   AltFire:
    RPTM ABC 2
    TNT1 A 0 A_CustomPunch(0, 0, 0, "RaptorMPuffDummy",85)
    RPTM D 1 A_CustomPunch(20, 0, 0, "RaptorMPuff",85)
    RPTM EFGH 1
    TNT1 A 13
    TNT1 A 1 A_ReFire
    Goto Ready 
   Flash:
    TNT1 A 2 Bright A_Light1
    Goto LightDone
   }
}

ACTOR RaptorPuff
{ 
    Mass 5
    Scale 0.50
    Radius 3
    Height 3
    +NOBLOCKMAP
    +NOGRAVITY
    -PUFFONACTORS
    Renderstyle TRANSLUCENT
    Alpha 0.8
    States
    {
    Spawn:
      RPPF AABCDE 1 BRIGHT
    Stop
    }
}

ACTOR RaptorMPuff
{
  +NOBLOCKMAP
  +NOGRAVITY
  +NOEXTREMEDEATH
  -PUFFONACTORS
  RenderStyle Translucent
  Alpha 0.5
  SeeSound "weapons/raptormhit"
  AttackSound "weapons/raptordeflect"
  ActiveSound "weapons/raptormelee"
  States
  {
  Spawn:
    RMPF AB 2
    RMPF C 1
    Stop
  }
} 
 
ACTOR RaptorMPuffDummy
{
  +NOBLOCKMAP
  +NOGRAVITY
  +NOEXTREMEDEATH
  +PUFFONACTORS
  SeeSound "weapons/raptormhit"
  States
  {
  Spawn:
    TNT1 A 1
    Stop
  }
}

[Voidic]

Also i gave it a slot thing heres the gameinfo thing:
gameinfo
 {
   weaponslot = 1, "Fist", "Chainsaw"
   weaponslot = 2, "Raptor"
   // add other slots here...
 }
 

[Nevander]

Change

ACTOR Raptor : Weapon

To

ACTOR Raptor : Weapon 15001

The number is arbitrary but you have to pick one that's not in use. The number adds it to map editors.

 

And add

Weapon.SlotNumber 2

To the weapon properties.

 

Delete gameinfo since you don't have a new player class.

Edited December 17, 2020 by Nevander

[Voidic]

Ok i put it to ACTOR Raptor : Weapon 15006 so where do a put the slot number thing

[Nevander]

You can just put it under kickback. Doesn't matter really but before states is best practice.

[Voidic]

Oh hey, it works! now how do i replace the deafalt pistol with it... Not tryna be rude or controlling or anything

Edited December 17, 2020 by StillChillBoi

[Voidic]

Oh wait i found it on discord