Decorate Monster Problem

[Zeg-Vok]

actor Rogor 10023
{
Health 15000
Radius 70
Height 60
Speed 16
Scale 1.4
Mass 10000
PainChance 32
MONSTER
+BOSS
+FLOAT
+SPAWNCEILING
+NOGRAVITY
+MissileMore
+MissileEvenmore
+LOOKALLAROUND
States
{
Spawn:
DRAG ABCDCB 6 A_Look
Loop
See:
DRAG AB 6 A_FastChase
DRAG C 0 A_CustomMissile("Rogorspawncloud", 0, 20, 0)
DRAG C 0 A_CustomMissile("Rogorspawncloud", 0, -20, 0)
DRAG CDCB 6 A_FastChase
Loop
Melee:
DRAG AB 4 A_FaceTarget
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, 20, 30)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, -20, 25)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, 20, 20)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, -20, 35)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, 20, 0)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, -20, 0)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, 20, 0)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, -20, 0)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, 20, 0)
DRAG C 0 A_CustomMissile("RogorAttackcloud", 0, -20, 0)
DRAG CDCB 4
Goto See
Missile:
DRAG A 0
DRAG A 0 A_JumpIfHealthLower(4500, 27) //If health is lower than 4500, then goto chance of SkullShot
DRAG A 0 A_Jump(30, 3) //Normal Missile
DRAG A 0 A_Jump(60, 8) //GassMissile2
DRAG A 0 A_Jump(90, 13) //Death Orbs
DRAG A 0 A_Jump(120, 17) //GassMissile
DRAG ABCD 4 A_FaceTarget // Normal Missles
DRAG E 0 A_CustomMissile("RogorMissile", 0, 0, 0)
DRAG E 0 A_CustomMissile("RogorMissile", 0, 20, 0)
DRAG E 4 A_CustomMissile("RogorMissile", 0, -20, 0)
DRAG DCB 4 A_FaceTarget
Goto See
DRAG ABCD 4 A_FaceTarget //Red Gass Missles
DRAG E 0 A_CustomMissile("RogorGassMissile2", 0, 0, 0)
DRAG E 0 A_CustomMissile("RogorGassMissile2", 0, 20, 0)
DRAG E 4 A_CustomMissile("RogorGassMissile2", 0, -20, 0)
DRAG DCB 4 A_FaceTarget
Goto See
DRAG ABCDCBABCD 4 A_FaceTarget //Death Orb Spawners
DRAG E 0 A_CustomMissile("DeathOrbSpawner", 150, -150, 90)
DRAG E 4 A_CustomMissile("DeathOrbSpawner", 150, 150, -90)
DRAG DCBABCDCB 4 A_FaceTarget
Goto See
DRAG ABCD 4 A_FaceTarget //Black Gass Missles
DRAG E 0 A_CustomMissile("RogorGassMissile", 0, 0, 0)
DRAG E 0 A_CustomMissile("RogorGassMissile", 0, 20, 0)
DRAG E 4 A_CustomMissile("RogorGassMissile", 0, -20, 0)
DRAG DCB 4 A_FaceTarget
Goto See
DRAG A 0 A_Jump(60, 1) //Chance for Rogor's Super Attack
Goto See //If the Jump Fails, goto the See State
DRAG A 0 A_SetInvulnerable
DRAG A 0 A_SetReflective
DRAG ABCDCBABCD 4 A_FaceTarget
DRAG E 6 A_CustomMissile("LostSoulSuperSpawner", 0, 0, 0)
DRAG DCB 4 A_FaceTarget
DRAG A 0 A_UnsetInvulnerable
DRAG A 0 A_UnsetReflective
Goto See
Pain:
DRAG F 4 A_Pain
DRAG G 4
Goto See
Death:
DRAG H 4 A_Scream
DRAG I 4 A_Fall
DRAG JKL 4
DRAG M -1
Stop
}
}


That is the code for one of the Monsters in my Project in the works, eveerything works except the Lost Soul Spawner part. I want it to pretty much add an extra Attack chance when his health is below 4500, but instead of just adding a chance to do an extra attack. It seems that when his health goes below 4500, all he does is the DeathOrb Spawn attack.

[Graf Zahl]

You counted the jumps wrong.

If you write

DRAG ABCDCBABCD 4 A_FaceTarget //Death Orb Spawners


it counts as 10 states, not 1.

[Zeg-Vok]

Ah, thanks!