WAD question

[FPS_noob]

I would like to create a WAD but have a question...

Could I edit character& weapons?

[lupinx-Kassman]

Yes, there are many editors to edit weapon sprites and attributes, but here are a couple I use.

http://www.doomworld.com/xwe/

That is for editing sprites (the way weapons and monsters look.)

http://www.teamhellspawn.com/exl/index.php?page=whacked2

That is for editing functions of weapons and monsters.

Now know, editing sprites is pretty simple once you understand how to use the program, but editing the behaviour of weapons and monsters is more difficult and will require you to obtain some knowledge on the way the Doom engine works. There are turorials. Read them.

[jobro]

Decorate is your friend when it comes to editing weapons and monsters.

Here is the pistol in Decorate form:

actor Pistol : Weapon
{
  obituary "%o was tickled by %k's pea shooter."
  attacksound "weapons/pistol"
  weapon.selectionorder 1900
  weapon.kickback 100
  weapon.ammotype "Clip"
  weapon.ammouse 1
  weapon.ammogive 20
  +WEAPON.WIMPY_WEAPON
  states
  {
  Ready:
    PISG A 1 A_WeaponReady
    loop
  Deselect:
    PISG A 1 A_Lower
    loop
  Select:
    PISG A 1 A_Raise
    loop
  Fire:
    PISG A 4
    // Next 2 states replace A_FirePistol
    PISG B 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    PISG B 6 A_GunFlash
    PISG C 4
    PISG B 5 A_ReFire
    goto Ready
  Flash:
    PISF A 7 bright A_Light1
    PISF A 0 bright A_Light0
    stop
  }
}

Let's take a look at the Fire section:

Fire: <- defines the name of the section
    PISG A 4 <- Animation A played 4 ticks
    PISG B 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff") <- Fires the bullet
    PISG B 6 A_GunFlash
    PISG C 4
    PISG B 5 A_ReFire <- Checks if firebutton is pressed
    goto Ready <- goes back to ready if not pressed.

So let's reshape the fire sequence to fire 3 shots at once:

Fire:
    PISG A 4
    // Next 2 states replace A_FirePistol
    PISG B 0 A_FireBullets (5.6, 0, 3, 5, "BulletPuff")
    PISG B 6 A_GunFlash
    PISG C 4
    PISG B 5 A_ReFire
    goto Ready

or fire 5 shots in a rapid burst of fire:

Fire:
    PISG A 4
    // Next 2 states replace A_FirePistol
    PISG B 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    PISG B 2 A_GunFlash
    PISG C 2
    PISG B 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    PISG B 2 A_GunFlash
    PISG C 2
    PISG B 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    PISG B 2 A_GunFlash
    PISG C 2
    PISG B 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    PISG B 2 A_GunFlash
    PISG C 2
    PISG B 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    PISG B 2 A_GunFlash
    PISG C 6
    PISG B 5 A_ReFire
    goto Ready

[madnessJack]

Yeah your best bet is ZDoom it has all these funky features like decorate and it's easy to implement too. Also, a relative promise of DoomScript for the future...

http://www.zdoom.org