Unintentionally Defying Gravity [WIP include]

[Kontra Kommando]

I don't understand what is the problem here...

http://www.mediafire.com/download/1w6oyamdm6a2l12/Terminator+WIP.zip

I've been working on an special death for the massive hunter-killer tanks in my terminator WAD. But for some odd reason, when they die, the actors that are gibs fly up into the stratosphere, and remain there continuously clipping. Perhaps its the monster's height? I've used the same coding for other monsters that I've done similar death's for. Perhaps someone could help me out, but taking a look under the hood.

Here is the decorate file in particular:

Actor HUNTERKILLERTANK 15666
{
Game Doom
Health 8000
Radius 125
Height 175
Speed 1
PainChance 200
Mass 9999999
Species Terminator
Monster
DamageFactor Railgun, 1.5
+FLOORCLIP
+NOBLOOD
+NOPAIN
+DONTHARMSPECIES
SeeSound "baby/sight"
DeathSound "baby/death"
Obituary "%o was terminated."
States
{
Spawn:
HKTK AA 3 A_Wander
HKTK A 0 A_Look
HKTK BB 3 A_Wander
HKTK B 0 A_Look
HKTK CC 3 A_Wander
HKTK C 0 A_Look
HKTK DD 3 A_Wander
HKTK D 0 A_Look
Loop
See:
HKTK AAAA 2 A_Chase
TNT1 A 0 A_BabyMetal
HKTK BBBB 2 A_Chase
HKTK CCCC 2 A_Chase
TNT1 A 0 A_BabyMetal
HKTK DDDD 2 A_Chase
Loop
Missile:
HKTK E 10 A_FaceTarget


HKTK F 6 BRIGHT A_CustomMissile("TerminatorBall", 32, 0, random(-8, 8), 0)
HKTK E 6 A_FaceTarget

HKTK F 6 BRIGHT A_CustomMissile("TerminatorBall", 32, 0, random(-8, 8), 0)
HKTK E 6 A_FaceTarget

HKTK F 6 BRIGHT A_CustomMissile("TerminatorBall", 32, 0, random(-8, 8), 0)
HKTK E 6 A_FaceTarget
Goto See
Forget:
HKTK A 0 A_TakeInventory("Forgettimer", 20)
HKTK A 3 A_ClearTarget
Goto Spawn
Death:
HKDE A 5
TNT1 A 0 A_SpawnItem("ExplosionDeath")
Stop
Raise:
T800 K 5
T800 JIH 5
Goto See
}
}

ACTOR DeadHKTank
{
Game Doom
SpawnID 149
Radius 125
Height 100
ProjectilePassHeight -16
+SOLID
States
{
Spawn:
HKDE ABC 1 Bright
Loop
}
}

ACTOR BasicHKTANKgib
{
Radius 6
Height 6
+NOBLOCKMAP
+CLIENTSIDEONLY
Mass 50
Scale 0.8
States
{
Spawn:
TNT1 A 1
Stop
}
}

ACTOR HKGIB1 : BasicHKTANKgib
{
States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath4")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
HKHE ABC 1
loop

}
}


ACTOR HKGIB2 : BasicHKTANKgib
{
States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath4")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
HKGN ABC 1
loop
}
}


ACTOR HKGIB3 : BasicHKTANKgib
{
States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath4")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
HKG1 A 1
loop
}
}


ACTOR HKGIB4 : BasicHKTANKgib
{
States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath2")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
HKG2 A 1
loop
}
}


ACTOR HKGIB5 : BasicHKTANKgib
{
States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath3")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
HKG3 ABC 1
loop
}
}

Actor ExplosionDeath : BasicHKTANKgib
{
Game Doom
Radius 125
Height 10
States
{
Spawn:
T800 H 5
TNT1 A 0 A_SpawnItem("DeadHKTank")
TNT1 A 0 A_SpawnItem("HKGIB1")
TNT1 A 0 A_SpawnItem("HKGIB2")
TNT1 A 0 A_SpawnItem("HKGIB3")
TNT1 AAA 0 A_SpawnItem("HKGIB4")
TNT1 AAA 0 A_SpawnItem("HKGIB5")
T800 I 5 A_Scream
T800 J 5 A_NoBlocking
T800 K 5
T800 L -1
stop
}
}

EDIT: Haven't made a credits page yet, this is a WIP with errors, not a release. There are other things I haven't include as well.

[Cat God25]

Because you used loop, they keep repeating the whole Spawn state.

HKGIB1

States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath4")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
HKHE ABC 1
loop
}

You could cut it into two different states so that only one part repeats, like:

States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath4")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
Goto Potato
Potato:
HKHE ABC 1
loop
}

The Spawn state should only play once, but Potato repeats over and over and over and over...

No more flying gibbies?

Hope this helps.

[Kontra Kommando]

Cat God25 said:

Because you used loop, they keep repeating the whole Spawn state.

HKGIB1

States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath4")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
HKHE ABC 1
loop
}

You could cut it into two different states so that only one part repeats, like:

States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySound("misc/xdeath4")
TNT1 A 0 ThrustThingZ(0,20,0,1)
TNT1 A 0 A_SetAngle(random(0, 359))
TNT1 A 0 A_Recoil(3)
Goto Potato
Potato:
HKHE ABC 1
loop
}

The Spawn state should only play once, but Potato repeats over and over and over and over...

No more flying gibbies?

Hope this helps.

I will surely look into this when I have a chance, thanks for your help dude