how can i make my machine gun shoots faster

hi, i have downloaded a M60 into my doom. and it uses ammotype: clip as default. is there any way to make the machine gun to shoot faster or increase the firing frequency?? i mean is it possible to change or add new definition to the existing ammo type??

this is the decorate of my M60:
----------------------------------------------------------------------
Actor Repeater : Weapon
{
Inventory.PickupSound "misc/w_pkup"
Inventory.PickupMessage "You got the plasma repeater!"
Obituary "%o was disintegrated by %k's repeater."
Weapon.AmmoType1 "AMCell"
Weapon.AmmoGive 20
Weapon.AmmoUse 1
+Weapon.Explosive
+Weapon.NoAlert
AttackSound "Weapons/RepeaterFire"
States
{
Spawn:
REPG I -1
Loop
Ready:
REPG A 0 A_TakeInventory("RepeaterSpin", 3)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG A 1 A_WeaponReady
Loop
Deselect:
REPG A 0 A_TakeInventory("RepeaterSpin", 3)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG A 1 A_Lower
Loop
Select:
REPG A 1 A_Raise
Loop
Fire:
//===========Spinup
REPG A 0 A_PlaySound("Weapons/RepeaterSpinup")
REPG A 0 A_JumpIfInventory("RepeaterSpin", 1, 8)
REPG A 0 A_JumpIfInventory("RepeaterB", 1, 4)
REPG A 0 A_JumpIfInventory("RepeaterC", 1, 4)
REPG A 0 A_JumpIfInventory("RepeaterD", 1, 4)
REPG A 4
REPG B 4
REPG C 4
REPG D 4 A_GiveInventory("RepeaterFrameA")
REPG A 0 A_JumpIfInventory("RepeaterSpin", 2, 9)
REPG A 0 A_GiveInventory("RepeaterSpin", 1)
REPG A 0 A_JumpIfInventory("RepeaterB", 1, 4)
REPG A 0 A_JumpIfInventory("RepeaterC", 1, 4)
REPG A 0 A_JumpIfInventory("RepeaterD", 1, 4)
REPG A 3
REPG B 3
REPG C 3
REPG D 3 A_GiveInventory("RepeaterFrameA")
REPG A 0 A_JumpIfInventory("RepeaterB", 1, 4)
REPG A 0 A_JumpIfInventory("RepeaterC", 1, 4)
REPG A 0 A_JumpIfInventory("RepeaterD", 1, 4)
REPG A 2
REPG B 2
REPG C 2
REPG D 2 A_GiveInventory("RepeaterFrameA")
//===========Fire
REPG A 0 A_Refire
//===========Spindown
REPG A 0 A_PlaySound("Weapons/RepeaterSpindown")
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DD 1 A_WeaponReady(11)
REPG A 0 A_TakeInventory("RepeaterSpin", 1)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AAA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BBB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CCC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DDD 1 A_WeaponReady(11)
REPG A 0 A_TakeInventory("RepeaterSpin", 1)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AAAA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BBBB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CCCC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DDDD 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AAAA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BBBB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CCCC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DDDD 1 A_WeaponReady(11)
Goto Ready
Hold:
//===========Fire
REPG E 0 Bright A_Gunflash
REPG E 0 Bright A_AlertMonsters
REPG E 2 Bright A_FireBullets(5, 4, 2, 6, "RepPuff", 1, 10240)
REPG F 2 Bright
REPG G 0 Bright A_AlertMonsters
REPG G 2 Bright A_FireBullets(5, 4, 2, 6, "RepPuff", 1, 10240)
REPG H 2 Bright
REPG A 0 A_Refire
//===========Spindown
REPG A 0 A_PlaySound("Weapons/RepeaterSpindown")
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DD 1 A_WeaponReady(11)
REPG A 0 A_TakeInventory("RepeaterSpin", 1)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AAA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BBB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CCC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DDD 1 A_WeaponReady(11)
REPG A 0 A_TakeInventory("RepeaterSpin", 1)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AAAA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BBBB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CCCC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DDDD 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameA", 1)
REPG AAAA 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameB", 1)
REPG BBBB 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameC", 1)
REPG CCCC 1 A_WeaponReady(11)
REPG A 0 A_GiveInventory("RepeaterFrameD", 1)
REPG DDDD 1 A_WeaponReady(11)
Goto Ready
Flash:
TNT1 A 2 A_Light2
TNT1 A 2 A_Light1
TNT1 A 0 A_Light0
Stop
}
}

Actor RepeaterSpin : Inventory { Inventory.MaxAmount 2 }
Actor RepeaterB : Inventory { Inventory.MaxAmount 1 }
Actor RepeaterC : Inventory { Inventory.MaxAmount 1 }
Actor RepeaterD : Inventory { Inventory.MaxAmount 1 }

Actor RepeaterFrameA : CustomInventory
{
Inventory.MaxAmount 0
+Inventory.AutoActivate
States
{
Spawn:
TNT1 A 1
Stop
Use:
TNT1 A 0 A_TakeInventory("RepeaterB", 1)
TNT1 A 0 A_TakeInventory("RepeaterC", 1)
TNT1 A 0 A_TakeInventory("RepeaterD", 1)
Stop
}
}

Actor RepeaterFrameB : RepeaterFrameA
{
States
{
Spawn:
TNT1 A 1
Stop
Use:
TNT1 A 0 A_GiveInventory("RepeaterB", 1)
TNT1 A 0 A_TakeInventory("RepeaterC", 1)
TNT1 A 0 A_TakeInventory("RepeaterD", 1)
Stop
}
}

Actor RepeaterFrameC : RepeaterFrameA
{
States
{
Spawn:
TNT1 A 1
Stop
Use:
TNT1 A 0 A_TakeInventory("RepeaterB", 1)
TNT1 A 0 A_GiveInventory("RepeaterC", 1)
TNT1 A 0 A_TakeInventory("RepeaterD", 1)
Stop
}
}

Actor RepeaterFrameD : RepeaterFrameA
{
States
{
Spawn:
TNT1 A 1
Stop
Use:
TNT1 A 0 A_TakeInventory("RepeaterB", 1)
TNT1 A 0 A_TakeInventory("RepeaterC", 1)
TNT1 A 0 A_GiveInventory("RepeaterD", 1)
Stop
}
}

Actor RepPuff
{
Radius 3
Height 3
RenderStyle Add
Alpha 0.75
+AlwaysPuff
+PuffOnActors
+NoGravity
+NoBlockMap
+PuffGetsOwner
+ForceRadiusDmg
+BloodlessImpact
Decal MummyScorch
States
{
Spawn:
RPUF A 1 Bright
RPUF A 0 Bright A_PlaySound("Weapons/RepeaterHit")
RPUF A 2 Bright A_Explode(7, 44, 0)
RPUF BCDEFG 3 Bright
Stop
}
}


Actor AMCell : Ammo
{
Inventory.PickupSound "misc/i_pkup"
Inventory.Amount 10
Inventory.MaxAmount 150
Ammo.BackpackAmount 10
Ammo.BackpackMaxAmount 300
Inventory.PickupMessage "You picked up an antimatter capsule."
Inventory.Icon WAMCA0
States
{
Spawn:
WAMC A 3 Bright
WAMC B 9
Loop
}
}

Actor AMBox : AMCell
{
Inventory.Amount 50
Inventory.PickupMessage "You picked up a box of antimatter capsules."
States
{
Spawn:
WAMC D 3 Bright
WAMC C 9
Loop
}
}
---------------------------------------------------------------------

hope some one can help me with this!

many thanks in advance!!
keith

keithktam said:

is there any way to make the machine gun to shoot faster or increase the firing frequency?? i mean is it possible to change or add new definition to the existing ammo type??

You do not need to define new ammo or modify the ammo definition. Instead, focus on the "fire" state. Try changing to the following:

//===========Fire
REPG E 0 Bright A_Gunflash
REPG E 0 Bright A_AlertMonsters
REPG E 1 Bright A_FireBullets(5, 4, 2, 6, "RepPuff", 1, 10240)
REPG F 1 Bright
REPG G 0 Bright A_AlertMonsters
REPG G 1 Bright A_FireBullets(5, 4, 2, 6, "RepPuff", 1, 10240)
REPG H 1 Bright
REPG A 0 A_Refire