Custom Monster Problem

Hi,

I'm trying to use this beastie from realm667: Core Tentacle

All of my other custom monsters work correctly except this one. He appears in DB2 ok but when I run the game all I get is an '!' in a diamond. I can't work out why.

Here's my DECORATE code:

actor Tentacle1 1042
{
//$Category monsters
  obituary "%o was snared by a tentacle"
  health 400
  radius 40
  height 112
  scale 0.75
  mass 9999999
  speed 0
  painchance 96
  seesound "monster/tensit"
  painsound "monster/tenpai"
  deathsound "monster/tendth"
  activesound "monster/tenact"
  MONSTER
  +BOSS
  +FLOORCLIP
  +DONTHURTSPECIES
  +NOTARGET
  +MISSILEEVENMORE
  -FULLVOLACTIVE
  states
  {
  Spawn:
    NULL A 10 A_Look
    loop
  See:
    TEN1 ABCD 4
    TEN1 EFGH 4 A_Chase
    goto See+4
  Missile:
    TEN1 F 5 A_FaceTarget
    TEN1 F 0 A_Jump(96,1)
    goto Missile1
    TEN1 F 0
    Goto Missile2
  Missile1:
    TEN1 I 8 A_FaceTarget
    TEN1 J 9 Bright A_CustomMissile("TentacleBall1",100,0,0,0,0)
    TEN1 I 8 A_FaceTarget
    TEN1 J 9 Bright A_CustomMissile("TentacleBall1",100,0,0,0,0)
    TEN1 I 8 A_FaceTarget
    TEN1 J 9 Bright A_CustomMissile("TentacleBall1",100,0,0,0,0)
    TEN1 I 8
    Goto See+4
  Missile2:
    TEN1 I 8 A_FaceTarget
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",10,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",20,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",30,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",40,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",50,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",60,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",70,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",80,0,0,0,0)
    TEN1 K 0 Bright A_CustomMissile("TentacleBall2",90,0,0,0,0)
    TEN1 K 9 Bright A_CustomMissile("TentacleBall2",100,0,0,0,0)
    Goto See+4  
  Pain:
    TEN1 L 3
    TEN1 L 3 A_Pain
    goto See+4
  Death:
    TEN1 M 4
    TEN1 N 4 A_Scream
    TEN1 O 4 A_NoBlocking
    TEN1 PQRS 4
    TEN1 T -1
    stop
  Raise:
    TEN1 ABCD 4
    goto See+4
  }
}

actor Tentacle2 : Tentacle1 1043
{
//$Category monsters
  +SPAWNCEILING
  +NOGRAVITY
  +DONTFALL
  states
  {
  Spawn:
    NULL A 10 A_Look
    loop
  See:
    TEN2 ABCD 4
    TEN2 EFGH 4 A_Chase
    goto See+4
  Missile:
    TEN2 F 5 A_FaceTarget
    TEN2 F 0 A_Jump(96,1)
    goto Missile1
    TEN2 F 0
    Goto Missile2
  Missile1:
    TEN2 I 8 A_FaceTarget
    TEN2 J 9 Bright A_CustomMissile("TentacleBall1",4,0,0,0,0)
    TEN2 I 8 A_FaceTarget
    TEN2 J 9 Bright A_CustomMissile("TentacleBall1",4,0,0,0,0)
    TEN2 I 8 A_FaceTarget
    TEN2 J 9 Bright A_CustomMissile("TentacleBall1",4,0,0,0,0)
    TEN2 I 8
    Goto See+4
  Missile2:
    TEN2 I 8 A_FaceTarget
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",10,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",20,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",30,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",40,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",50,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",60,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",70,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",80,0,0,0,0)
    TEN2 K 0 Bright A_CustomMissile("TentacleBall2",90,0,0,0,0)
    TEN2 K 9 Bright A_CustomMissile("TentacleBall2",100,0,0,0,0)
    Goto See+4  
  Pain:
    TEN2 L 3
    TEN2 L 3 A_Pain
    goto See+4
  Death:
    TEN2 M 4
    TEN2 N 4 A_Scream
    TEN2 O 4 A_NoBlocking
    TEN2 PQRS 4
    TEN2 T -1
    stop
  Raise:
    TEN2 ABCD 4
    goto See+4
  }
}

actor TentacleBall1
{
  radius 4
  height 4
  speed 25
  damage 10
  renderstyle Add
  alpha 0.75
  seesound "monster/tenatk"
  deathsound "weapons/plasmax"
  PROJECTILE
  +RANDOMIZE
  states
  {
  Spawn:
    TNFX ABCD 3 bright
    loop
  Death:
    TNFX EFGHIJK 4 bright
    stop
  }
}

actor TentacleBall2 : TentacleBall1
{
  speed 10
  damage 5
  seesound "imp/attack"
  deathsound "imp/shotx"
  PROJECTILE
  +RANDOMIZE
  states
  {
  Spawn:
    TNFX LM 3 bright
    loop
  Death:
    TNFX NOP 4 bright
    stop
  }
}
Any suggestions please?

Thanks,

Dave

Share this post


Link to post

Open the console and look at the messages. When ZDoom spawns an Unknown thing, it logs the reason to the console.

Possible reasons include:
- Bad editor number. Message: "Unknown type %i at (%i, %i)\n"
- No sprite for spawn state. Message: "%s at (%i, %i) has no frames\n"

If there is no message, then it is caused by a RandomSpawner going through an infinite loop.


Now I guess that the problem here is the second variety:

  Spawn:
    NULL A 10 A_Look
    loop
NULL isn't a valid sprite! If you want a spriteless spawn state, use TNT1.

Share this post


Link to post

Cheers Gez.

I've been able to spawn the monster successfully using ACS, I suspect that this monster would work best as an ambush spawner and is actually supposed to work that way, so i'm happy with that. It would've been nice of the uploader on realm667 to add some instructions though!!

Dave

Share this post


Link to post

Sometimes this happens to me. I get around it by spawning them where I want with a script.

Share this post


Link to post

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now